
####################################################################

プロローグ:

StopBGM
StartBGM kt_soldiers.mid

Hide
ChangeMap \Map\荒野.map 非同期

Create ＮＰＣ サテライト社製ＶＭＡクラウドフェザー(近接戦闘型) 0 地球連盟軍兵士(ザコ) 4 14 16 Ｅ
Create ＮＰＣ サテライト社製ＶＭＡクラウドフェザー(狙撃型) 0 地球連盟軍兵士(ザコ) 4 7 17 Ｙ
Create ＮＰＣ サテライト社製ＶＭＡクラウドフェザー(汎用攻撃型) 0 地球連盟軍兵士(ザコ) 4 11 18 Ｗ
Create ＮＰＣ サテライト社製ＶＭＡクラウドフェザー(指揮官機) 0 地球連盟軍兵士(ザコ) 4 12 16 Ｊ 
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 4 13 13 あ
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 0 タドゥオス星系人製ＡＩ(ザコ) 4 11 14 い
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 0 タドゥオス星系人製ＡＩ(ザコ) 4 12 12 う
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 0 タドゥオス星系人製ＡＩ(ザコ) 4 7 10 え
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 4 6 11 お
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 0 タドゥオス星系人製ＡＩ(ザコ) 4 5 9 く
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 4 18 13 
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 4 19 14
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 0 タドゥオス星系人製ＡＩ(ザコ) 4 16 10
Center 11 13
Show
Wait 5
Night
Wait 5
日付表示 西暦2133年　6月15日 オーストラリア　シドニー基地周辺
Wait Click
ClearPicture
Noon
Wait 10

PlaySound AI.wav
Talk い 11 14
…………………
End

Select い
SelectTarget Ｊ
戦闘アニメ_小型ミサイル攻撃 2
戦闘アニメ_迎撃発動
Wait 5

Talk リーン＝カーライル 12 16
今です、隊長！
Talk ジャック＝コールソン(攻撃) 12 16
分かっている！
End

Select Ｊ
SelectTarget い
戦闘アニメ_グレネード投げ攻撃
SelectTarget あ
戦闘アニメ_ヘビーマシンガン準備
戦闘アニメ_ヘビーマシンガン攻撃
SelectTarget い
戦闘アニメ_グレネード命中 1
SelectTarget あ
戦闘アニメ_ヘビーマシンガン命中
Destroy い
Destroy あ
Wait 10

Talk ジャック＝コールソン(真剣) 12 16
シエラ２、シエラ４！
Talk ウィリアム＝Ｌ＝ケネディ 11 18
了解です！
Talk エメリア＝フランフォード(攻撃２) 14 16
任せといて、隊長！
End
Wait 5

PlaySound Drill.wav
Move Ｗ 11 12 アニメ表示
Wait 2
PlaySound Drill.wav
Move Ｅ 13 12 アニメ表示
Wait 5

Center う
Select Ｗ
SelectTarget う
戦闘アニメ_振る武器準備 "Anime\woh_Cannon(Hammer).bmp" 40 Reload.wav
Select Ｅ
SelectTarget う
戦闘アニメ_ビームソード準備 グリーン Beamsaber.wav
Select Ｗ
SelectTarget う
戦闘アニメ_振る武器突撃攻撃 "Anime\woh_Cannon(Hammer).bmp" 40 Drill.wav
Select Ｅ
SelectTarget う
戦闘アニメ_ビームソード突撃攻撃 グリーン Drill.wav
Select Ｗ
SelectTarget う
戦闘アニメ_強打命中 Crash.wav
Select Ｅ
SelectTarget う
戦闘アニメ_ビームソード命中 グリーン
Destroy う
Wait 10

PlaySound Whiz.wav
Move お 9 12 アニメ表示
Move え 11 11 アニメ表示
Wait 5

Talk ウィリアム＝Ｌ＝ケネディ 11 12
しまっ――
End
Select Ｙ
SelectTarget え
戦闘アニメ_ロックオン攻撃
戦闘アニメ_ライフル攻撃 "Weapon\EFFECT_AntiMaterialRifle01.bmp" 64
戦闘アニメ_ライフル命中
Wait 5
Destroy え
Wait 10

Talk ユキノ＝ナザーロフ 7 17
ウィル、油断しないで……
Talk ウィリアム＝Ｌ＝ケネディ 11 12
す…すみません、ユキノさん
Suspend
Wait 5
PlaySound AI.wav
Talk お 9 12
…………………
End
Wait 5
PlaySound Whiz.wav
Move お 7 14 アニメ表示
Wait 5

Talk ユキノ＝ナザーロフ 7 17
懲りない奴……
End

Create 敵 タドゥオス星系人製無人兵器Ａ５７ 0 タドゥオス星系人製ＡＩ(ザコ) 4 1 16 か
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 4 2 17 き
Wait 10

PlaySound Whiz.wav
Move か 4 16 アニメ表示
Move き 5 17 アニメ表示
Wait 5

Talk ユキノ＝ナザーロフ 7 17
…ッ！
End

Select Ｙ
SelectTarget き
戦闘アニメ_対物ライフル準備
戦闘アニメ_ライフル攻撃 "Weapon\EFFECT_AntiMaterialRifle01.bmp" 64
SelectTarget か
戦闘アニメ_ライフル攻撃 "Weapon\EFFECT_AntiMaterialRifle01.bmp" 64
SelectTarget き
戦闘アニメ_ライフル命中
SelectTarget か
戦闘アニメ_ライフル命中
Wait 5
Destroy き
Destroy か
Wait 10

Talk ユキノ＝ナザーロフ 7 17
次……
Talk ジャック＝コールソン(攻撃) 12 16
いかん、下がれシエラ３！
Talk ユキノ＝ナザーロフ 7 17
え……
End
PlaySound Whiz.wav
Move お 7 16 アニメ表示
Wait 5

Escape お
Explode M 7 17
Wait 10

Talk エメリア＝フランフォード(攻撃２) 13 12
ユキノ！
Talk リーン＝カーライル 12 16
シエラ３、応答して！
Suspend
Wait 5
PlaySound Noise.wav
Talk システム 7 17
……………
Suspend
Wait 5
PlaySound AI.wav
Talk く 5 9
………………
End
PlaySound Whiz.wav
Move く 5 14 アニメ表示
Wait 5

Talk ウィリアム＝Ｌ＝ケネディ 11 12
くっ…！
End
Wait 5
PlaySound Drill.wav
Move Ｗ 7 14 アニメ表示
Wait 5

Talk ウィリアム＝Ｌ＝ケネディ 7 14
お前達、よくもユキノさんを！
End
Select Ｗ
SelectTarget く
戦闘アニメ_マシンガン準備 "Anime\woh_MachinGun(2)B.bmp" 32
戦闘アニメ_マシンガン攻撃 "Anime\woh_MachinGun(2)B.bmp" 32
戦闘アニメ_マシンガン命中
Destroy く
Wait 10

Create 敵 タドゥオス星系人製無人兵器Ａ３５ 0 タドゥオス星系人製ＡＩ(ザコ) 4 3 6
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 0 タドゥオス星系人製ＡＩ(ザコ) 4 5 5
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 0 タドゥオス星系人製ＡＩ(ザコ) 4 7 2
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 4 8 5 
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 4 8 7
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 0 タドゥオス星系人製ＡＩ(ザコ) 4 10 4
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 4 12 3
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 0 タドゥオス星系人製ＡＩ(ザコ) 4 12 6
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 0 タドゥオス星系人製ＡＩ(ザコ) 4 14 7
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 0 タドゥオス星系人製ＡＩ(ザコ) 4 16 5
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 0 タドゥオス星系人製ＡＩ(ザコ) 4 17 6
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 4 18 4
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 0 タドゥオス星系人製ＡＩ(ザコ) 4 19 8
Wait 10

PlaySound AI.wav
Talk タドゥオス星系人製ＡＩ(ザコ) 12 6
……………………
Talk リーン＝カーライル 12 16
12時の方向より、敵の増援部隊です！
Talk エメリア＝フランフォード(怒り) 13 12
もう、これじゃキリが無いわ！
Talk ジャック＝コールソン(ダメージ) 12 16
……………………
どうやら、この辺が潮時か。
Talk ジャック＝コールソン(真剣) 12 16
どうやら、この辺が潮時か。シエラ１より各機へ、;一旦退くぞ！
ウィル、俺とエメリアが援護する。君がユキノを;連れて行け！
Talk ウィリアム＝Ｌ＝ケネディ 7 14
り、了解です！
End
Wait 5
PlaySound Drill.wav
Move Ｗ 7 16 アニメ表示
Wait 5
PlaySound TransForm.wav
Wait 5
Talk ウィリアム＝Ｌ＝ケネディ 7 16
接続確認。ＯＫです隊長！
Talk ジャック＝コールソン(真剣) 12 16
よし、シエラ３とシエラ４をカバーしつつ後退、戦域を離脱する！
Talk エメリア＝フランフォード(怒り) 13 12
全く、世話が焼けるんだから…！
Talk ウィリアム＝Ｌ＝ケネディ 7 16
(ユキノさん、どうかご無事で…)
End
PlaySound Drill.wav
Hide
Wait 10

StopBGM
StartBGM DS-fi01.mid
背景 \BG\YAKUIN00.jpg 640 480
Show
場所表示 地球連盟軍シドニー基地　執務室
Wait 10

PlaySound Page.wav
Talk ジャック＝コールソン
報告は以上です……
Talk ソフィア＝コールドウェル
ご苦労だった中尉。しかし浮かない顔をしているな
Talk ジャック＝コールソン(ダメージ)
部下を危険な目に遭わせればこうもなります…
Talk ソフィア＝コールドウェル
おやおや、『死神』の台詞とは思えないな。もう慣れたと思っていたぞ
Talk ジャック＝コールソン(真剣)
ご冗談を。あんな感覚に慣れてしまっては終わりです
自分もこれ以上、遺族への手紙は書きたくは;ありませんから
Talk ソフィア＝コールドウェル
だが、戦場ではよくある事だ。命があっただけでも;儲け物だとは思わんか？
むしろ貴様らの生還率の高さが異常なだけだ
Talk ジャック＝コールソン(困惑)
残念ですが、自分はそこまで単純には考えられません。部下を危険に晒したのは事実なのですから
Talk ソフィア＝コールドウェル
ほう、言うようになったなジャック……
Talk ジャック＝コールソン
自分の独り言です。聞き流して下さい
Talk ソフィア＝コールドウェル
フン、まぁ良い。:次の命令は追って通達する。もう下がって良い
せいぜい、可愛い部下達に死神の呪いが及ばぬよう祈る事だ
Talk ジャック＝コールソン(真剣)
ええ、善処しますよ。:では、失礼します！
End
PlaySound AutoDoor(Open).wav
Call 暗転
ClearPicture
Wait 10

StopBGM
StartBGM crime_m.mid

Hide
Talk システム
………
……
…
Talk ニコライ＝ナザーロフ セピア
ユキノ、俺達狙撃兵は任務のためならば、ターゲットに何日も張り付く事がある
つまり、そいつらの好きな食い物や日課、家族や恋人の事、それら全てを知った上で引き金を引くんだ
Talk ユキノ＝ナザーロフ(過去) セピア
……？
Talk ニコライ＝ナザーロフ セピア
いや、すまん。お前にはまだ難しいな。:;良いさ、理論より実践だ！
Suspend
Wait 5
PlaySound Reload.wav
Talk ニコライ＝ナザーロフ セピア
よく見てろ、引き金を引く時は獲物と呼吸を合わせる。:そうすりゃ……
Suspend
PlaySound Hittyuu.wav
Wait 10
PlaySound Rifle.wav
Wait 10
PlaySound Stab.wav
Talk 熊 セピア
グアァァァッ！
Suspend
PlaySound FallDown.wav
Wait 10
Talk ニコライ＝ナザーロフ セピア
よし、命中！
Talk ユキノ＝ナザーロフ(過去) セピア
お父さん、あのクマさん、死んじゃったの…？
Talk ニコライ＝ナザーロフ セピア
あいつは最近農作物を食い荒らしててな。近くの農家から駆除依頼も出てたんだ
ま、お前が気にする事じゃないさ
Talk ユキノ＝ナザーロフ(過去) セピア
…………
Suspend
Wait 5
PlaySound CallTone.wav
Talk ニコライ＝ナザーロフ セピア
おっと、もうこんな時間か。だいぶ冷えてきたな…
そろそろ帰るか。:今日の夜は母さんがボルシチを;作ってくれてるぞ
Talk ユキノ＝ナザーロフ(過去) セピア
ホントに！？
Talk ニコライ＝ナザーロフ セピア
ははっ、お前の大好物だったな
あまり遅くなるとメシ抜きだ。急いで帰るぞ！
Talk ユキノ＝ナザーロフ(過去)(笑い) セピア
は〜い♪
End
Wait 10

StopBGM

背景 \BG\byousitu.jpg 640 480
Show
場所表示 ？？？
Wait 10

Talk ユキノ＝ナザーロフ(包帯)
……………
夢……？
Suspend
Wait 5
PlaySound AutoDoor.wav
Talk エメリア＝フランフォード
ようやくお目覚めね。お姫様
Talk ユキノ＝ナザーロフ(包帯)
エメリア……
Talk エメリア＝フランフォード(困惑)
あ〜あ、美人が台無しね。悔しいけど、あんたツラは良いからねぇ
Talk ユキノ＝ナザーロフ(包帯)
ここは……？
Suspend
StartBGM Your Epitaph.mid
場所表示 シドニー基地　軍病院
Talk エメリア＝フランフォード(困惑)
見ての通り、基地の病院よ
あんたは昨日の戦闘で負傷して、ここに担ぎ;込まれたわけ
Talk ユキノ＝ナザーロフ(包帯)
……………
Talk エメリア＝フランフォード(困惑)
ウィル君に感謝しなさいよ。あの子が運んで来なければ、あんたは今頃消し炭になってたんだから
Talk ユキノ＝ナザーロフ(包帯)
ウィル……
Talk エメリア＝フランフォード
で、みんなで交代で看病してたんだけど、もう必要;無いわね
Talk エメリア＝フランフォード(困惑)
それじゃ――
Talk ユキノ＝ナザーロフ(包帯)
エメリア
Talk エメリア＝フランフォード
どうかした？
Talk ユキノ＝ナザーロフ(包帯)
……………
ありがとうございます
Talk エメリア＝フランフォード(怒り)
え……:あ……:うん、分かれば良いのよ
Talk エメリア＝フランフォード(困惑)
じゃ、しっかり養生しなさいよ
End
PlaySound AutoDoor(Open).wav
Call 暗転
ClearPicture
Wait 10

PaintPicture \BG\sf_level1903_a.jpg 0 0 640 480 - - 保持
PaintPicture \CutIn\GNC_CloudFeather_SDFU.png 160 237 192 192 透過
PaintPicture \Weapon\EFFECT_BusterBeamLauncher01.bmp 122 262 144 144 - - 透過 右回転 90
場所表示 シドニー基地　格納庫
Refresh
Wait 10

Talk ジャック＝コールソン(笑い)
そうか、ユキノも目を覚ましたか
Talk エメリア＝フランフォード
はい、ですが目を少し怪我したみたいで、１週間は;安静だそうです
Talk ウィリアム＝Ｌ＝ケネディ
１週間……
Talk リーン＝カーライル
当分は彼女抜きで編成を考えなければなりませんね
Talk ジャック＝コールソン(真剣)
ああ、しかし命に別状が無くて何よりだった。俺もこれ以上部下を失うのはご免だからな
Talk リーン＝カーライル
隊長……
Talk ジャック＝コールソン
いや、すまない。『死神』と呼ばれ続けていると;どうしてもそんな風に考えてしまってな…
Talk エメリア＝フランフォード(困惑)
それにしてもユキノがあたしに礼を言うなんて、明日は弾丸の雨が降るかも知れないわ
Talk リーン＝カーライル
言い過ぎよ、エメリア
Talk ウィリアム＝Ｌ＝ケネディ
ところで隊長、このクラウドフェザーの装備は何ですか？
Talk ジャック＝コールソン
ああ、VMA用の高出力ビーム砲だ。北米方面軍で;試験運用されていた物が１つ手に入ってな
なんでも従来の約2.5倍のパワーがあるそうだ
Talk ウィリアム＝Ｌ＝ケネディ
凄い、戦艦並の威力ですね！:　これならインベーダーとの戦いも――
Talk ジャック＝コールソン
だが、その反面エネルギー消費も半端ではない。;２、３発ほどでVMAのエネルギーが空になるらしい
Talk エメリア＝フランフォード(困惑)
それじゃ役に立ちませんって
Talk ジャック＝コールソン
確かにな。そのため本体側にも大容量エネルギー;パックを装備する
火力と引き換えに機動性を犠牲にしたわけだ
Talk ウィリアム＝Ｌ＝ケネディ
扱いは難しそうですね……
Talk ジャック＝コールソン
まずは周辺の射爆場で試射を行いたいところだが、問題のパイロットがな…
Talk リーン＝カーライル
ユキノの復帰を待たねばなりませんね
Talk ジャック＝コールソン(真剣)
ああ、コイツは彼女でなければ使いこなせんだろう
Talk エメリア＝フランフォード(困惑)
何だかんだ言っても、銃の扱いに関してはあいつが;小隊で１番ですからね
Talk ジャック＝コールソン
当面はこちらの装備のテストを優先しよう
Suspend
Wait 5
PlaySound WindowOpen.wav
Color RGB(50,50,50)
Line 180 180 300 300 BF
PaintPicture \Event\サーマル・センサー.jpg - - フィルタ RGB(119,255,119) 50%
Refresh
Wait 5
Talk ジャック＝コールソン
新型の熱源探知センサーだ。:技術的に目新しい物;ではないが、精度は格段に向上しているとの事だ
Talk ウィリアム＝Ｌ＝ケネディ
武器ばかりではないんですね
Talk ジャック＝コールソン(真剣)
いくら強力な武器だろうと、それを有効に運用出来る環境が無ければ宝の持ち腐れだ
Talk ジャック＝コールソン
まぁ、いくら装備を整えても、最後にものを言うのは;パイロットの力なんだがな
Talk ウィリアム＝Ｌ＝ケネディ
………………
Suspend
Wait 5
PlaySound WindowClose.wav
ClearPicture
PaintPicture \BG\sf_level1903_a.jpg 0 0 640 480 - - 保持
PaintPicture \CutIn\GNC_CloudFeather_SDFU.png 160 237 192 192 透過
PaintPicture \Weapon\EFFECT_BusterBeamLauncher01.bmp 122 262 144 144 - - 透過 右回転 90
場所表示 シドニー基地　格納庫
Refresh
Talk ジャック＝コールソン
しばらくは３機での編成となる。ユキノがいつ戻って;来ても良いように、俺達が――
Suspend
StopBGM
StartBGM batof3_gm.mid
PlaySound Warning(2).wav
Wait 20
PlaySound WindowOpen.wav
Talk 地球連盟軍兵士(ザコ) フィルタ RGB(119,255,119) 50%
総員に告ぐ。当基地に向け、インベーダーの無人;兵器群が接近中
第一種戦闘配備発令！ 当直のVMAパイロット以下戦闘員は直ちに出撃準備を――
Talk エメリア＝フランフォード(怒り)
まさか、ここに敵が攻めてきたっての！？
Talk ジャック＝コールソン(真剣)
連中も馬鹿ではない。一気に本丸を陥とすつもり;なのだろう
Talk リーン＝カーライル
そんな……
Talk ウィリアム＝Ｌ＝ケネディ
もし、ここが陥落したら反攻作戦は――
Talk ジャック＝コールソン(真剣)
実施される事もなく失敗だ。ここには反攻作戦の主力部隊も駐留しているからな
奴らの思い通りにさせるわけにはいかん。何としても守り抜くぞ！
Talk エメリア＝フランフォード(怒り)
了解、責任重大ですね…！
Talk ウィリアム＝Ｌ＝ケネディ
隊長、僕達もすぐにVMAに――
Talk ジャック＝コールソン
忘れたのか？ 俺達の機体はオーバーホールのために地下格納庫へ移されているんだ
Talk リーン＝カーライル
まずは機体の確保が先決ですね
Talk ジャック＝コールソン(真剣)
ああ、既に作業は完了しているはずだ。すぐに取りに行くぞ！
Talk ウィリアム＝Ｌ＝ケネディ
了解です！
End
Call 暗転
ClearPicture
Wait 10

ChangeMap -.map 非同期
Cls
Show
PaintPicture \Anime\CU_Back\EFFECT_base_back01.gif - - 485 305 透過 保持
PaintPicture \CutIn\GNC_BanderSnatchG[2]Full.png 70 210 64 64 透過 保持
場所表示 地球連盟軍シドニー基地
Refresh
Wait 10
PlaySound Walk(Robot).wav
PaintPicture \CutIn\GNC_Askalon_SDFU.png 420 240 64 64 透過
PaintPicture \Anime\EFFECT_GNC_VMAMachineGunD.bmp 410 258 32 32 透過
Refresh
Wait 5
PlaySound Walk(Robot).wav
PaintPicture \CutIn\GNC_Askalon_SDFU.png 400 300 72 72 透過
PaintPicture \Anime\EFFECT_GNC_VMAMachineGunD.bmp 388 318 36 36 透過
Refresh
Wait 10

Talk 地球連盟軍兵士(ザコ) 左右反転
敵は目の前だ。実弾の入ったライフルをくれ！
Talk 地球連盟軍兵士(ザコ)
各機、これは演習ではない！ 気を引き締めていくぞ！
End
Wait 5

PlaySound Drill.wav

For i = 1 To 25
	ClearPicture
	wait start
	Color RGB(20,20,100)
	Line 0 32 480 84 BF
	Font RGB(255,255,255)
	Font 16pt Ｐ明朝 Bold
	PaintString - 48 地球連盟軍シドニー基地
	PaintPicture \CutIn\GNC_Askalon_SDFU.png (420 - (i * i)) 240 64 64 透過
	PaintPicture \Anime\EFFECT_GNC_VMAMachineGunD.bmp (410 - (i * i)) 258 32 32 透過
	PaintPicture \CutIn\GNC_Askalon_SDFU.png 400 300 72 72 透過
	PaintPicture \Anime\EFFECT_GNC_VMAMachineGunD.bmp 388 318 36 36 透過
	Refresh
	wait 0.1
Next
PlaySound Drill.wav
For i = 1 To 25
	ClearPicture
	wait Start
	Color RGB(20,20,100)
	Line 0 32 480 84 BF
	Font RGB(255,255,255)
	Font 16pt Ｐ明朝 Bold
	PaintString - 48 地球連盟軍シドニー基地
	PaintPicture \CutIn\GNC_Askalon_SDFU.png (400 - (i * 20)) 300 72 72 透過
	PaintPicture \Anime\EFFECT_GNC_VMAMachineGunD.bmp (388 - (i * 20)) 318 36 36 透過
	Refresh
	wait 0.1
Next
Wait 10

場所表示 地球連盟軍シドニー基地
PlaySound Stairs(Run).wav
Talk エメリア＝フランフォード(怒り)
演習ではない？ 当たり前でしょ！
Talk ウィリアム＝Ｌ＝ケネディ
よりによってこんな時に手元に機体が無いなんて…！
Talk ジャック＝コールソン
世の中、そう思い通りには行かないさ
Talk ジャック＝コールソン(真剣)
世の中、そう思い通りには行かないさ。それよりも今は先を急ぐぞ！
Talk リーン＝カーライル
了解です、隊長！
End
Call 暗転
ClearPicture
Wait 10

PaintPicture \BG\sf_level1903_a.jpg 0 0 640 480 - - 保持
PaintPicture \CutIn\GNC_CloudFeatherII_SDFU.png 280 242 160 160 透過
PaintPicture \CutIn\GNC_CloudFeather_SDFU.png 160 237 192 192 透過
PaintPicture \CutIn\GNC_CloudFeather_SDFU.png 20 235 224 224 透過
場所表示 シドニー基地　地下格納庫
Refresh
StopBGM
StartBGM kimyo_gm.mid
KeepBGM
Wait 10

PlaySound Computer.wav
Talk リーン＝カーライル
メインジェネレーター点火、:各関節のロックを解除、:FCSオンライン、:データリンク正常――
Talk ジャック＝コールソン
機体の機嫌が良い。整備班の連中に感謝せねばな
Suspend
Wait 5
PlaySound WindowOpen(2).wav
Talk ウィリアム＝Ｌ＝ケネディ フィルタ RGB(119,255,119) 50%
こちらシエラ４、出撃準備完了です
Talk エメリア＝フランフォード フィルタ RGB(119,255,119) 50%
隊長、こっちもＯＫです！
Talk ジャック＝コールソン(真剣)
よし、既に戦闘は始まっている。俺達もすぐに;上に向かう
敵の数は多い。予備弾の携行も忘れるなよ！
End
Call 暗転
ClearPicture
Wait 10

wait Start
PlaySound Charge(2).wav
For i = 1 To 200
	ClearPicture
	PaintPicture \Event\elevator.jpg 0 0 480 480 - - 保持
	PaintPicture \Event\base.png (400 - (i * 3)) (500 - (i * 3)) 300 300 透過
	PaintPicture \CutIn\GNC_CloudFeather_SDFU.png (450 - (i * 3)) (490 - (i * 3)) 96 96 - - 透過
	PaintPicture \CutIn\GNC_CloudFeather_SDFU.png (550 - (i * 3)) (490 - (i * 3)) 96 96 - - 透過
	PaintPicture \CutIn\GNC_CloudFeatherII_SDFU.png (490 - (i * 3)) (500 - (i * 3)) 100 100 - - 透過
	Refresh
	wait untill (i * 0.3)
Next

Exit

####################################################################

スタート:

Hide
Wait 5

ChangeMap \Map\シドニー基地外周.map 非同期
Create ＮＰＣ ダイナミクス社製ＶＭＡアスカロン 0 地球連盟軍兵士(ザコ) 9 4 13
Create ＮＰＣ ダイナミクス社製ＶＭＡアスカロン 0 地球連盟軍兵士(ザコ) 8 3 14
Create ＮＰＣ ダイナミクス社製ＶＭＡバンダースナッチ 0 地球連盟軍兵士(ザコ) 8 5 14
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 8 11 7 
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 8 13 7 
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 8 9 7 
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 1 タドゥオス星系人製ＡＩ(ザコ) 8 10 6
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 1 タドゥオス星系人製ＡＩ(ザコ) 8 12 6
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 0 タドゥオス星系人製ＡＩ(ザコ) 8 4 5
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 0 タドゥオス星系人製ＡＩ(ザコ) 8 8 5
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 1 タドゥオス星系人製ＡＩ(ザコ) 9 6 4
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 0 タドゥオス星系人製ＡＩ(ザコ) 8 5 3
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 0 タドゥオス星系人製ＡＩ(ザコ) 8 7 3
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 0 タドゥオス星系人製ＡＩ(ザコ) 8 14 5
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 0 タドゥオス星系人製ＡＩ(ザコ) 9 18 5
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 1 タドゥオス星系人製ＡＩ(ザコ) 8 16 4
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 0 タドゥオス星系人製ＡＩ(ザコ) 8 15 3
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 0 タドゥオス星系人製ＡＩ(ザコ) 8 17 3
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 1 タドゥオス星系人製ＡＩ(ザコ) 8 4 1 待機１
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 1 タドゥオス星系人製ＡＩ(ザコ) 8 6 1 待機１
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 1 タドゥオス星系人製ＡＩ(ザコ) 8 16 1 待機１
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 1 タドゥオス星系人製ＡＩ(ザコ) 8 18 1 待機１
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 2 タドゥオス星系人製ＡＩ(ザコ) 9 11 3 代表
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 1 タドゥオス星系人製ＡＩ(ザコ) 9 10 2 待機２
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 1 タドゥオス星系人製ＡＩ(ザコ) 9 12 2 待機２
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 1 タドゥオス星系人製ＡＩ(ザコ) 9 9 1 待機２
Create 敵 タドゥオス星系人製無人兵器Ａ３５ 1 タドゥオス星系人製ＡＩ(ザコ) 9 13 1 待機２
Create 敵 タドゥオス星系人製無人兵器キャリアーＤ１４ 1 タドゥオス星系人製ＡＩ(中)(ザコ) 10 11 1 船
ChangeMode 待機１ 固定
ChangeMode 待機２ 固定
ChangeMode 船 固定
ChangeMode 代表 固定
SetStatus 代表 不死身 -1
Center 14 8
Show
Wait 5
Night

Wait 5
日付表示 西暦2133年　6月17日 地球連盟軍シドニー基地
Wait Click
ClearPicture
Noon
Wait 10

Launch ジャック 15 16
Launch エメリア 14 17
Launch ウィル 16 17
Item 予備弾薬
Item 予備弾薬
Item 予備弾薬
Equip ジャック 予備弾薬
Equip エメリア 予備弾薬
Equip ウィル 予備弾薬
Wait 10

Talk ウィリアム＝Ｌ＝ケネディ
僕達の基地が……
Talk ジャック＝コールソン(真剣)
クッ、ここまで敵の侵入を許すとはな…！
Talk リーン＝カーライル
隊長、コールドウェル少佐より緊急通信です
Suspend
Wait 5
PlaySound WindowOpen.wav
Talk ソフィア＝コールドウェル フィルタ RGB(119,255,119) 50%
コールソン中尉、聞こえるか？
Talk ジャック＝コールソン(真剣)
少佐、どの程度の敵が入り込んでいるんです？
Talk ソフィア＝コールドウェル フィルタ RGB(119,255,119) 50%
ミサイルで３割は撃墜したが、100機は下らんだろう
第４小隊は第17VMA小隊と共にこのＷブロックを死守、敵部隊を撃滅せよ
Talk ジャック＝コールソン
了解しました！
Suspend
Wait 5
PlaySound WindowClose.wav
Talk エメリア＝フランフォード(怒り)
全く、少佐も簡単に言ってくれるわ
Talk ウィリアム＝Ｌ＝ケネディ
それだけ期待されているって事ですよ
Talk エメリア＝フランフォード(困惑)
はぁ、給料上げて欲しいわね…
Talk ジャック＝コールソン
シエラ１より各機へ、聞いての通りだ。これより我々は基地防衛戦に移行する
明日の戦局のためにも、この基地を失うわけにはいかん
Talk ジャック＝コールソン(真剣)
何より、俺達の家に土足で踏み入った罪は重い。奴らには相応の報いを受けさせてやれ！
Talk エメリア＝フランフォード(怒り)
シエラ２、了解！
Talk ウィリアム＝Ｌ＝ケネディ
シエラ４、了解です！
Talk ジャック＝コールソン(攻撃)
戦闘開始だ。全員、死ぬなよ！
End

タイトル Episode-03 緋眼の射手
StopBGM

####  勝利条件  ################################################################

勝利条件:
If ボーナス達成 Then
	勝利条件表示 敵の全滅 味方機の撃墜 Episode-03　緋眼の射手 ボーナス条件 無し
ElseIf ボス登場 Then
	勝利条件表示 敵の全滅  味方機の撃墜 Episode-03　緋眼の射手 ボーナス条件 ユキノ機でタンク・ゴーレムを破壊する。
Else
	勝利条件表示 敵の全滅 味方機の撃墜 Episode-03　緋眼の射手 ボーナス条件 ？？？
EndIf
Exit


ターン 全 味方:
If 包帯ユキノ Then
	StartBGM DS-ba02.mid
	KeepBGM
ElseIf ボス登場 Then
	StartBGM kt_soldiers.mid
	KeepBGM
Else
	StartBGM DS-ba04.mid
	KeepBGM
EndIf
Exit

####  会話イベント  ################################################################

攻撃 ジャック 敵:
Talk リーン＝カーライル
射程内に入りました。攻撃可能です！
Talk ジャック＝コールソン(真剣)
まさか奴らがここまで大規模な攻勢に出るとはな…
Talk ジャック＝コールソン(攻撃)
だが、ここに手を出したからにはただでは済まさんぞ！
End
ClearEvent
Exit

攻撃 エメリア 敵:
Talk エメリア＝フランフォード(怒り)
…………………
Talk エメリア＝フランフォード(攻撃２)
覚悟は良いわね？ ユキノの仇、討たせてもらうわよ！
Talk ウィリアム＝Ｌ＝ケネディ
まだ死んでませんって！
End
ClearEvent 
Exit

攻撃 ユキノ 敵:
Talk ユキノ＝ナザーロフ
…………………
End
Hide
Talk ニコライ＝ナザーロフ セピア
だからユキノ、トリガーを引く時は何も考えるな。:ただ、己が命じるままに敵を撃て
殺す相手の人生まで背負おうなんてのは、ただの;傲慢なのさ
End
Show
Talk ユキノ＝ナザーロフ
…………………
父さん……
End
ClearEvent 
Exit

攻撃 ウィル 敵:
Talk ウィリアム＝Ｌ＝ケネディ
僕達の基地から出て行け、インベーダー！
End
ClearEvent 
Exit

攻撃 味方 ボス:
Talk ウィリアム＝Ｌ＝ケネディ
くっ、なんて火力だ。近付けない…！
Talk ジャック＝コールソン
流石は艦船用のビーム砲だ。VMAの装甲では;気休めにもならんな
リーン、チャージにかかる時間は分かるか？
Talk リーン＝カーライル
およそ１分です
Talk エメリア＝フランフォード(怒り)
離れればビーム、かといって近付いても取り巻き;の歓迎パーティ――
全く、どうやって倒せばいいのよ…？
Talk ジャック＝コールソン(攻撃)
まだ何か手はあるはずだ。簡単に諦めるな！
Talk ジャック＝コールソン(真剣)
シエラ１より各機へ、ビーム砲と本体のゴーレムに;攻撃を集中しろ
武器さえ潰してしまえば、デカいだけのガラクタだ！
Talk ユキノ＝ナザーロフ
…………………
End
ClearEvent 
Exit

####  イベント色々  ################################################################

破壊 味方:
GameOver
Exit

ターン 2 味方:
FadeOut 25
Hide

Wait 10
背景 \BG\byousitu.jpg 640 480
Show
場所表示 シドニー基地　軍病院
PlaySound Explode(Far).wav
Wait 10

Talk ユキノ＝ナザーロフ(包帯)
この音……:まさか、戦闘…？
Talk 地球連盟軍兵士(ザコ)
おい聞いたか？ 奴らがこの基地に直接攻撃を;かけてきたらしいぞ
Talk 地球連盟軍兵士(ザコ) 左右反転
クソッ、この怪我さえなけりゃ奴らを血祭りに;上げられたってのに…！
Talk 地球連盟軍兵士(ザコ)
やめておけ、返り討ちにされるだけだ
Suspend
Wait 5
PlaySound Walk(Robot).wav
Talk ユキノ＝ナザーロフ(包帯)
………………
Talk 地球連盟軍兵士(ザコ)
おい曹長、どこへ行くつもりだ？ お前さんだって;病人だろう
Talk ユキノ＝ナザーロフ(包帯)
………………
行かなきゃ…！
End
PlaySound Stairs(Run).wav
Call 暗転
Wait 10

Show
Redraw
Exit

ターン 3 味方:
FadeOut 25
Hide
PaintPicture \BG\sf_level1903_a.jpg 0 0 640 480 - - 保持
PaintPicture \CutIn\GNC_CloudFeather_SDFU.png 160 237 192 192 透過
PaintPicture \Weapon\EFFECT_BusterBeamLauncher01.bmp 122 262 144 144 - - 透過 右回転 90
場所表示 シドニー基地　格納庫
Refresh
Show
PlaySound Stairs(Run).wav
Wait 10

Talk ユキノ＝ナザーロフ(包帯)
あった。:でも、この装備は……
Suspend
Wait 5
PlaySound AutoDoor(Open).wav
Talk ソフィア＝コールドウェル
怪我人が病室を抜け出すとは、感心せんな曹長
Talk ユキノ＝ナザーロフ(包帯)
少佐、どうしてここに…？
Talk ソフィア＝コールドウェル
万が一に備え、研究データのバックアップを取りに;来たのさ
ここの責任者は私だからな
Talk ユキノ＝ナザーロフ(包帯)
…………………
少佐、無理を承知でお願いします。この機体を――
Talk ソフィア＝コールドウェル
残念だが、怪我人に任せられる機体は無い。仮に出撃したとしても仲間の足を引っ張るだけだ
それに貴様は狙撃兵だ。そんな目で何が出来る;というのだ？
Talk ユキノ＝ナザーロフ(包帯)
問題ありません。私の利き目は左目です。砲台代わりにはなります…
Talk ソフィア＝コールドウェル
その装備はまだ試作品だ。命の保障は出来んぞ？
Talk ユキノ＝ナザーロフ(包帯)
覚悟の上です。
Talk ソフィア＝コールドウェル
…………………
Talk ユキノ＝ナザーロフ(包帯)
…………………
Talk ソフィア＝コールドウェル
…………………
Talk ユキノ＝ナザーロフ(包帯)
…………………
Talk ソフィア＝コールドウェル
…………………
フッ、良いだろう。好きにするがいい
Talk ユキノ＝ナザーロフ(包帯)
良いんですか……？
Talk ソフィア＝コールドウェル
覚悟があると言ったのは貴様だろう。ならば余計な;言葉は不要だ
だが、自らの言葉には責任を持てよ
Talk ユキノ＝ナザーロフ(包帯)
はい………
End
Call 暗転
Wait 10
ClearStatus 代表 不死身
Exit

ターン 5 敵:
ChangeMode 待機１ 通常
Exit

破壊 船:
獲得アイテム表示 応急補修キット
Exit

破壊 代表:
Wait 5

StopBGM
StartBGM kt_soldiers.mid
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 1 タドゥオス星系人製ＡＩ(ザコ) 8 3 8 
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 1 タドゥオス星系人製ＡＩ(ザコ) 8 2 7
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 1 タドゥオス星系人製ＡＩ(ザコ) 8 4 7 
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 1 タドゥオス星系人製ＡＩ(ザコ) 8 18 8 
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 1 タドゥオス星系人製ＡＩ(ザコ) 8 17 7
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 1 タドゥオス星系人製ＡＩ(ザコ) 8 19 7 
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 2 タドゥオス星系人製ＡＩ(ザコ) 8 9 7 まんたー
Create 敵 タドゥオス星系人製無人兵器Ａ５７ 2 タドゥオス星系人製ＡＩ(ザコ) 8 12 7 まんたー
ForEach 敵
	IncreaseMorale 10
Next
Wait 10

Talk ウィリアム＝Ｌ＝ケネディ
上から…！？
Talk リーン＝カーライル
隊長、上空より敵の増援部隊です！
Talk エメリア＝フランフォード(怒り)
ちょっと、空軍は何やってんのよ！？
Talk ジャック＝コールソン(真剣)
この物量差だ。突破されたらしいな
End
Wait 10

Create 敵 タドゥオス星系人製無人兵器Ａ５７ 1 タドゥオス星系人製ＡＩ(ザコ) 8 3 12 生贄１
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 8 2 13 生贄２
Create 敵 タドゥオス星系人製無人兵器Ａ１８ 0 タドゥオス星系人製ＡＩ(ザコ) 8 4 11 生贄３
Create 敵 ダミー 0 タドゥオス星系人製ＡＩ(ザコ) 8 18 16 だみー 非同期
Wait 10

Center 13 16
PlaySound Whiz.wav
Move 生贄１ 13 16 アニメ表示
Move 生贄２ 11 16 アニメ表示
Move 生贄３ 13 14 アニメ表示
Wait 10

Talk リーン＝カーライル
さらに９時の方向より新手の敵部隊を確認、発電施設へ向かっています！
Suspend
Wait 5
PlaySound AI.wav
Talk 生贄１
…………………
Talk ジャック＝コールソン(ダメージ)
クッ、ここからでは間に合わん…！
End
Wait 5
StopBGM
Wait 5

Select だみー
SelectTarget 生贄３
戦闘アニメ_小ビーム命中 ピンク
Destroy 生贄３
Escape だみー
Wait 10

Talk ウィリアム＝Ｌ＝ケネディ
今のは…
Talk ジャック＝コールソン(真剣)
ビーム攻撃だと！？
End
Wait 10

StopBGM
StartBGM DS-ba02.mid
KeepBGM
UpGrade サテライト社製ＶＭＡクラウドフェザー(狙撃型) サテライト社製ＶＭＡクラウドフェザー(ビーム砲装備型)
Launch ユキノ 18 16
Equip ユキノ 包帯ユキノ
IncreaseMorale ユキノ 10
Wait 10

Select ユキノ
SelectTarget 生贄１
戦闘アニメ_粒子集中準備 ピンク
戦闘アニメ_バスタービームライフル準備 "Weapon\EFFECT_BusterBeamLauncher01.bmp" 64 64
戦闘アニメ_バスタービームライフル攻撃  ピンク "Weapon\EFFECT_BusterBeamLauncher01.bmp" 64 64
Center 生贄１
戦闘アニメ_大ビーム命中 ピンク
SelectTarget 生贄２
戦闘アニメ_大ビーム命中 ピンク
Wait 2.5
Destroy 生贄１
Destroy 生贄２
Wait 10

Talk リーン＝カーライル
クラウドフェザー、:だけどあの装備は……
Talk エメリア＝フランフォード
…………………
Talk エメリア＝フランフォード(怒り)
まさか！
Suspend
Wait 5
PlaySound WindowOpen(2).wav
Talk ユキノ＝ナザーロフ
そのまさかです……
Talk ウィリアム＝Ｌ＝ケネディ
ユキノさん！
Talk ジャック＝コールソン(ダメージ)
馬鹿な、君はまだ病院で療養中のはずでは――
Suspend
Wait 5
PlaySound WindowOpen.wav
Talk ソフィア＝コールドウェル フィルタ RGB(119,255,119) 50%
私が許可した
Talk ジャック＝コールソン(ダメージ)
少佐、どういうつもりです？ 負傷した兵を戦わせる;など正気ですか！？
Talk ソフィア＝コールドウェル フィルタ RGB(119,255,119) 50%
勘違いしてもらっては困る。これはあくまでナザーロフ曹長の意思だ
Talk ウィリアム＝Ｌ＝ケネディ
え……
Talk リーン＝カーライル
本当なの、ユキノ？
Talk ユキノ＝ナザーロフ
はい、状況はどうあれ今は戦わねばならない時です
それに、エメリアに任せていては落ち着いて;休めませんから…
Talk エメリア＝フランフォード(怒り)
どういう意味よ！？
Talk ソフィア＝コールドウェル X(ジャック) Y(ジャック) フィルタ RGB(119,255,119) 50%
今は少しでも戦力が欲しい。心配ならば貴様ら;が守ってやれ
Talk ジャック＝コールソン
…………………
了解しました。:シエラ１より各機へ、シエラ３を中心に;戦闘を継続する
Talk ユキノ＝ナザーロフ
隊長、私の機は発電施設から電源をもらっているため移動出来ません
援護をお願いします……
Talk ジャック＝コールソン(笑い)
心配するな。君には指一本触れさせんよ
Talk ジャック＝コールソン(真剣)
心配するな。君には指一本触れさせんよ。だが、くれぐれも無茶はしないでくれ
Talk ユキノ＝ナザーロフ
はい………
Talk ウィリアム＝Ｌ＝ケネディ
…………………
End
ChangeMode 敵 通常
ChangeMode まんたー ユキノ
Set 包帯ユキノ
Exit

全滅 敵:
If ボス登場 Then
	GoTo エンディング
Else
Wait 5
Talk リーン＝カーライル
敵部隊の全滅を確認、他のブロックでも我が軍が;押し始めたようです
Talk ジャック＝コールソン
了解した。周辺警戒に移行する
Talk エメリア＝フランフォード(困惑)
ふぅ、なんとか帰る場所は守れたわね…
Talk ウィリアム＝Ｌ＝ケネディ
ええ、兵舎には秘蔵のジャパニメーションソフトがあります
無事に済んでほっとしましたよ
Talk エメリア＝フランフォード(困惑)
あー、ウィル君にとって命より大事な物だからね〜
Talk ユキノ＝ナザーロフ
……………………
End
Wait 10
Create ＮＰＣ ダイナミクス社製ＶＭＡアスカロン 0 地球連盟軍兵士(ザコ) 9 16 9 Ａ
Create ＮＰＣ ダイナミクス社製ＶＭＡアスカロン 0 地球連盟軍兵士(ザコ) 9 17 8 Ｂ
Create ＮＰＣ ダイナミクス社製ＶＭＡアスカロン 0 地球連盟軍兵士(ザコ) 9 17 10 Ｃ
Create ＮＰＣ ダイナミクス社製ＶＭＡバンダースナッチ 0 地球連盟軍兵士(ザコ) 8 18 9 Ｄ
Create ＮＰＣ 地球連盟製陸走戦艦アーカシア 0 地球連盟軍指揮官(ザコ) 9 20 9 船２
Create 敵 ダミー 0 タドゥオス星系人製ＡＩ(ザコ) 8 13 9 だみー２ 非同期
Wait 10
PlaySound Tone.wav
Talk Ａ
こちらは第24VMA小隊だ。Ｎブロックの敵は片付けた。:我々は残存の敵部隊を追撃する
Talk ジャック＝コールソン
了解した。ある程度数は減らしたが、奴らの物量は;脅威だ。十分に注意してくれ
Talk Ａ
ああ、後始末は俺達に任せて――
End
StopBGM
Wait 10
Select だみー２
SelectTarget 船２
戦闘アニメ_大ビーム命中 イエロー
Destroy 船２
Escape だみー２
StartBGM kt_soldiers.mid
KeepBGM
PlaySound Warning(2).wav
Wait 10
Talk ジャック＝コールソン(真剣)
何だ、今の攻撃は！？
Talk エメリア＝フランフォード(怒り)
嘘でしょ！？ 戦艦を一撃で沈めるなんて…
Talk リーン＝カーライル
こちらからは視認出来ません。敵の長距離攻撃と;思われます！
Talk ウィリアム＝Ｌ＝ケネディ
ですが、インベーダーに長距離攻撃が可能な個体は確認されていないはずです
Talk ユキノ＝ナザーロフ
新型……？
End
Wait 10
Create 敵 タドゥオス星系人製無人兵器Ａ３５Ｔ 0 タドゥオス星系人製ＡＩ(中)(ザコ) 12 5 9 ボス 非同期
BossRank 1
PlaySound Shock(low).wav
Call 揺れ 5 9 - 20
Wait 10
Talk ウィリアム＝Ｌ＝ケネディ
お、大きい……！
Talk エメリア＝フランフォード(怒り)
何よあれ、奴らの戦車ですか！？
Talk ジャック＝コールソン(真剣)
そのようだ。サイズが桁違いだかな……
Talk Ａ
クソッ、これ以上は通さん！
End
Center 10 9
Wait 5
PlaySound Drill.wav
Move Ａ 9 9 アニメ表示
Wait 2.5
PlaySound Drill.wav
Move Ｂ 10 8 アニメ表示
Wait 2.5
PlaySound Drill.wav
Move Ｃ 10 10 アニメ表示
Wait 2.5
PlaySound Drill.wav
Move Ｄ 11 9 アニメ表示
Wait 10
Talk ジャック＝コールソン(攻撃)
待て、迂闊に近付くな！
Suspend
Wait 5
PlaySound AI.wav
Talk ボス
……………………
End
Wait 10
Select ボス
SelectTarget Ａ
戦闘アニメ_粒子集中準備 イエロー
戦闘アニメ_大ビーム攻撃 イエロー
Center 10 9
戦闘アニメ_大ビーム命中 イエロー
SelectTarget Ｄ
戦闘アニメ_大ビーム命中 イエロー
Destroy Ａ
Destroy Ｄ
Wait 10
Talk Ｂ
隊長、バリー！
Talk Ｃ 左右反転
この野郎、やりやがったな！
End
Wait 5
PlaySound Drill.wav
Move Ｂ 7 8 アニメ表示
Wait 2.5
PlaySound Drill.wav
Move Ｃ 7 10 アニメ表示
Wait 5
Talk Ｂ 
こんなデカブツ、取り付いちまえば――
End
Create 敵 タドゥオス星系人製無人兵器Ａ３６ 1 タドゥオス星系人製ＡＩ(ザコ) 10 5 7 ガンゴ
Create 敵 タドゥオス星系人製無人兵器Ａ３６ 1 タドゥオス星系人製ＡＩ(ザコ) 10 5 11
Create 敵 タドゥオス星系人製無人兵器Ａ３７ 1 タドゥオス星系人製ＡＩ(ザコ) 10 6 8
Create 敵 タドゥオス星系人製無人兵器Ａ３７ 1 タドゥオス星系人製ＡＩ(ザコ) 10 6 10 ソーゴ
ForEach 敵
IncreaseMorale 20
Next
Wait 10
Talk Ｂ 
な……！
End
Select ガンゴ
SelectTarget Ｂ
戦闘アニメ_中ビーム攻撃 イエロー
戦闘アニメ_中ビーム命中 イエロー
Select ソーゴ
SelectTarget Ｃ
戦闘アニメ_振り下ろし攻撃
戦闘アニメ_振り下ろし命中
Destroy Ｂ
Destroy Ｃ
Wait 10
Talk ジャック＝コールソン(ダメージ)
クッ、やはり１機ではなかったか…！
Talk ウィリアム＝Ｌ＝ケネディ
ゴーレムの改良型のようですね
End
SpecialPowerAnime 偵察 ボス
Wait 5
PlaySound Computer.wav
Talk リーン＝カーライル
隊長、敵機のビーム砲の解析結果が出ました
89％の確率で、我が軍の宇宙艦艇に装備されている;タイプです！
Talk エメリア＝フランフォード(困惑)
え……
Talk ジャック＝コールソン
どうやら、我が軍のものを奪って使っているらしいな
Talk ユキノ＝ナザーロフ
ドロボー……
Suspend
Wait 5
PlaySound WindowOpen.wav
Talk ソフィア＝コールドウェル X(ジャック) Y(ジャック) フィルタ RGB(119,255,119) 50%
HQより第４小隊各機へ、全員無事か？
Talk ジャック＝コールソン(真剣)
全機健在です少佐。ですが、予想外の強敵に;出くわしたようです
Talk ソフィア＝コールドウェル フィルタ RGB(119,255,119) 50%
こちらでも確認した。進行ルートから察するに、敵の;狙いは中央司令部だろう
Talk ジャック＝コールソン(真剣)
ご心配なく。敵が何者であろうと、ここで食い止めます…！
Talk ソフィア＝コールドウェル フィルタ RGB(119,255,119) 50%
頼もしいな。:他のブロックへも増援を要請したが、当てには出来ん
貴様らの働きに期待する
Talk ジャック＝コールソン
了解しました。:シエラ１より各機へ、これより敵巨大;兵器を破壊する
Talk ジャック＝コールソン(真剣)
固まっていては的になる。散開して仕留めるぞ！
Talk ウィリアム＝Ｌ＝ケネディ
シエラ４、了解！
Talk エメリア＝フランフォード(攻撃２)
シエラ２了解、こりゃ狩り甲斐あるわね！
Talk ユキノ＝ナザーロフ
隊長、あのデカブツは私に任せて下さい。このビーム砲で仕留めます
Talk ジャック＝コールソン(真剣)
ああ、そいつの火力は奴への対抗手段として申し分無い。しかし、無理はするなよ
Talk ユキノ＝ナザーロフ
シエラ３、了解……
Talk ジャック＝コールソン(攻撃)
よし、第２ラウンド開始だ。全員、死ぬなよ！
End
UnSet 包帯ユキノ
Set ボス登場
勝利条件表示 敵の全滅 味方機の撃墜 Episode-03　緋眼の射手 ボーナス条件 F:ユキノ機でタンク・ゴーレムを破壊する。
EndIf

Exit

破壊 ボス:

If 相手ユニット = ユキノ＝ナザーロフ Then
	ボーナスアイテム表示 サーマル・センサー
EndIf
Set ボーナス達成
Exit

####  エンディング  ######################################################
   

エンディング:

Call 勝利条件達成
Wait 5
Hide

StartBGM gion.mid
ChangeMap \Map\シドニー基地外周.map 非同期
Launch ジャック 15 13 非同期
Launch エメリア 17 11 非同期
Launch ユキノ 18 16 非同期
Launch ウィル 13 12 非同期
Launch ボス 16 9
Create 敵 ダミー 0 タドゥオス星系人製ＡＩ(ザコ) 8 16 14 だみー３ 非同期
Create 敵 ダミー 0 タドゥオス星系人製ＡＩ(ザコ) 8 12 11 だみー４ 非同期
Center 15 11
Show
Wait 10

Explode M 16 9
SelectTarget ボス
戦闘アニメ_放電命中
Wait 10

Talk ジャック＝コールソン(真剣)
やったか！？
Suspend
Wait 5
PlaySound AI.wav
Talk ボス
………………
Talk リーン＝カーライル
駄目です。敵機の温度が下がっていません！
Talk エメリア＝フランフォード(怒り)
もう、タフな奴ね。いい加減倒れなさいよ！
Talk ウィリアム＝Ｌ＝ケネディ
せめて、本体ユニットに喰らわせる事が出来れば…
Talk エメリア＝フランフォード(困惑)
冗談、あいつの正面に立つなんて自殺行為でしょ
Talk ユキノ＝ナザーロフ
…………………
お願いがあります隊長、奴の周りに煙幕を張って下さい
Talk ジャック＝コールソン
煙幕だと？
Talk ウィリアム＝Ｌ＝ケネディ
敵の視界を奪うんですね！
Talk エメリア＝フランフォード(怒り)
でも、それはこっちも一緒よ
Talk ユキノ＝ナザーロフ
大丈夫です。それは私にとって問題にはなりません…
Talk リーン＝カーライル
どういう意味…？
Talk ジャック＝コールソン
………！
Talk ジャック＝コールソン(真剣)
なるほど、そういう事か…！
シエラ１より各機へ、合図を同時に奴にスモーク;グレネードを投射しろ
Talk エメリア＝フランフォード
隊長、どうするんですか？
Talk ジャック＝コールソン
説明している暇はない。今は俺の指示に従ってくれ
Talk ウィリアム＝Ｌ＝ケネディ
了解です！
End
Select ジャック
SelectTarget ボス
戦闘アニメ_グレネード投げ攻撃
Select エメリア
SelectTarget ボス
戦闘アニメ_グレネード投げ攻撃
Select ウィル
SelectTarget ボス
戦闘アニメ_グレネード投げ攻撃

PlayEffect 煙 16 10 Explode(Small).wav
PlayEffect 煙 17 8 Explode(Small).wav
PlayEffect 煙 15 9 Explode(Small).wav
Wait 10

PlaySound Interference.wav
ColorFilter RGB(200,200,200) 10%
Refresh
ColorFilter RGB(200,200,200) 20%
Refresh
ColorFilter RGB(200,200,200) 30%
Refresh
ColorFilter RGB(200,200,200) 40%
Refresh
ColorFilter RGB(200,200,200) 50%
Refresh
ColorFilter RGB(200,200,200) 60%
Refresh
ColorFilter RGB(200,200,200) 70%
Refresh
Wait 10

PlaySound AI.wav
Talk ボス
！？！？！？！？！？
End

Select ボス
SelectTarget だみー３
戦闘アニメ_大ビーム攻撃 イエロー
SelectTarget だみー４
戦闘アニメ_２連小ビーム攻撃 イエロー

Explode M 16 14
Explode M 12 11
Escape だみー３
Escape だみー４
Wait 10

Talk エメリア＝フランフォード(怒り)
うわっ、メチャクチャに撃ってきましたよ！
Talk ジャック＝コールソン
敵も精密機械だ。こういう野蛮な手段には;弱いと見える
Talk ウィリアム＝Ｌ＝ケネディ
ですが、敵の姿が見えなければ手の打ちようが…
Talk ジャック＝コールソン(真剣)
いや、はっきりと見えているさ
Suspend
StopBGM
Talk ユキノ＝ナザーロフ
…………………
End
Hide
Talk ニコライ＝ナザーロフ セピア
トリガーを引く時は決して躊躇うな。でなきゃ、本当に大切なものを失う事になる
『後悔先に立たず』だ。:俺と同じ過ちは繰り返さんでくれよ
End
Show
StartBGM yayk_gm.mid
Talk ユキノ＝ナザーロフ
…………………
分かってるわ、父さん……
End
Select ユキノ
SelectTarget ボス
戦闘アニメ_粒子集中準備 ピンク
戦闘アニメ_バスタービームランチャー準備
Talk ユキノ＝ナザーロフ
私は、大切なものを守るために引き金を引く…！
End


戦闘アニメ_ロックオン攻撃
戦闘アニメ_バスタービームランチャー攻撃 ピンク
戦闘アニメ_バスタービームランチャー命中
Wait 5
PlaySound AI.wav
Talk ボス
！？！？！？！？！？
End
戦闘アニメ_連続描画命中 Anime\Explode\EFFECT_SuperExplode(Orange)[01-12].gif 160 7 1 前面 Explode(Nuclear).wav 発光
Redraw
Escape ボス
Wait 10

PlaySound Interference.wav
ColorFilter RGB(200,200,200) 60%
Refresh
ColorFilter RGB(200,200,200) 50%
Refresh
ColorFilter RGB(200,200,200) 40%
Refresh
ColorFilter RGB(200,200,200) 30%
Refresh
ColorFilter RGB(200,200,200) 20%
Refresh
ColorFilter RGB(200,200,200) 10%
Refresh
ColorFilter RGB(200,200,200) 0%
Refresh
Wait 10

Talk ウィリアム＝Ｌ＝ケネディ
凄い、一撃で仕留めるなんて…
Talk リーン＝カーライル
敵大型機動兵器の撃破を確認しました
Talk ジャック＝コールソン
ユキノ、見事な射撃だったぞ
Talk ユキノ＝ナザーロフ
いえ……
Talk エメリア＝フランフォード(困惑)
で、どういうカラクリだったんです隊長？
Talk ユキノ＝ナザーロフ
これです……
Suspend
Wait 5
PlaySound Click.wav
Color RGB(50,50,50)
Line 180 180 300 300 BF
PaintPicture \Event\サーマル・センサー.jpg - - フィルタ RGB(119,255,119) 50%
Refresh
Wait 5
Talk ジャック＝コールソン
ユキノの機体には例の新型熱源センサーが装備;されていた
Talk ウィリアム＝Ｌ＝ケネディ
そうか、だからあの中でも正確な射撃が出来たんですね！
Talk エメリア＝フランフォード(困惑)
確かにあんなデカブツなら、発する熱も半端じゃない;ですからね〜
Suspend
Wait 5
PlaySound WindowClose.wav
ClearPicture
Talk ジャック＝コールソン
だが、それを成し得たのはユキノ自身の力だ。誇っていい
Talk ユキノ＝ナザーロフ
いえ、隊長も私を信じてくれてありがとうございました…
Talk ジャック＝コールソン(笑い)
部下を信じるのも、隊長の務めだからな
Suspend
Wait 5
PlaySound WindowOpen.wav
Talk ソフィア＝コールドウェル フィルタ RGB(119,255,119) 50%
ご苦労だった中尉、どうやら切り抜けたようだな
Talk ジャック＝コールソン(笑い)
ええ、我が隊の名射手のおかげですよ
Talk ユキノ＝ナザーロフ
…………………
Talk ソフィア＝コールドウェル 15 13 フィルタ RGB(119,255,119) 50%
フッ、彼女に感謝する事だ
他のブロックの敵も掃討した。貴様らもすぐに帰還しろ
Talk ジャック＝コールソン
了解しました。
Talk ジャック＝コールソン(真剣)
了解しました。シエラ１より各機へ、任務完了だ。;全員で帰還する！
End
Hide
PlaySound Drill.wav
Wait 10

ChangeMap -.map
StopBGM
StartBGM Delicious Strawberry.mid
背景 \BG\byousitu.jpg 640 480
Show
場所表示 シドニー基地　軍病院
Wait 10

Talk ユキノ＝ナザーロフ(包帯)
………………
なんで………？
Talk リーン＝カーライル
当然でしょう。いくら基地防衛の功労者といっても、怪我人には違いないんだから
Talk ウィリアム＝Ｌ＝ケネディ
しばらくは安静にして下さい
Talk ジャック＝コールソン(笑い)
そういう事だ。早く治して戻ってきてくれ
Talk ユキノ＝ナザーロフ(包帯)
はい………
Talk エメリア＝フランフォード(困惑)
良いわよね〜。今は休んでるだけで給料になるんだから
Talk リーン＝カーライル
エメリア！
Talk ユキノ＝ナザーロフ(包帯)
………………
運動不足で、エメリアみたいになってしまいます……
Talk エメリア＝フランフォード(怒り)
なんですって…！？
Talk ユキノ＝ナザーロフ(包帯)
失礼しました。どのみちあなたはリーンのような凹凸のあるプロポーションとは無縁でしたね…
Talk ジャック＝コールソン
(凹凸……？)
Talk リーン＝カーライル
ちょっと、何言ってるのよユキノ！
Talk エメリア＝フランフォード(怒り)
言ったわねこの根暗女！ あたしよりちょっと胸が;大きいからって調子に乗るんじゃないわよ！
Talk ウィリアム＝Ｌ＝ケネディ
そ、そうなんですか……？
Talk ユキノ＝ナザーロフ(包帯)
ふ……:負け犬の遠吠えですね…
Talk エメリア＝フランフォード(攻撃２)
このっ、口が減らないわね…！;少しは痛い目を見なきゃ分かんないかしら？
Talk ユキノ＝ナザーロフ(包帯)
こっちの台詞です…！
Talk ジャック＝コールソン(困惑)
頼むから、病院で騒がないでくれ……
End
Call 暗転
Wait 10

StopBGM
StartBGM forgot.mid
背景 \BG\YAKUIN00.jpg 640 480
Show
場所表示 地球連盟軍シドニー基地　執務室
Wait 10

PlaySound Page.wav
Talk ソフィア＝コールドウェル
ではブラウン司令、オーストラリア方面軍からも部隊を派遣します
Suspend
Wait 5
PlaySound WindowOpen.wav
Talk エドワード＝ブラウン フィルタ RGB(119,255,119) 50%
うむ、北米ネスト攻略作戦も近い。協力に感謝する
Talk ソフィア＝コールドウェル
いえ、この作戦は我ら人類の反撃の狼煙となるべき;ものです
オーストラリア方面軍も協力は惜しまぬよう仰せ;つかっています
Talk エドワード＝ブラウン フィルタ RGB(119,255,119) 50%
ありがたい事だ。必ずやネストを陥落させてご覧に入れる
Talk ソフィア＝コールドウェル
ところで、『Ｆ．Ｇ計画』は順調のようですね
Talk エドワード＝ブラウン フィルタ RGB(119,255,119) 50%
……！
貴官、どこでそれを…！？
Talk ソフィア＝コールドウェル
連盟も一枚岩では無いという事です
この戦局を打開するための一大プロジェクトだというのに、外部への情報開示がほとんど無い……
ブラウン司令、あなたの狙いは何です？
Talk エドワード＝ブラウン フィルタ RGB(119,255,119) 50%
…………………
この計画は極秘裏に進められている。君達が知る;必要は無い
君達は増援を振り向けてくれるだけで良い
Talk ソフィア＝コールドウェル
その増援は私の部下です
部下を死地に送り出すからには、不明瞭な点は;はっきりさせておきたいものです
Talk エドワード＝ブラウン フィルタ RGB(119,255,119) 50%
コールドウェル少佐、この命令は参謀本部で決定;された事だ。無用な詮索は控えた方が身のためだ
切れ過ぎる頭は、いずれ己を滅ぼす事になるかも;知れんぞ
Talk ソフィア＝コールドウェル
…………………
Suspend
Wait 5
PlaySound CallTone.wav
Talk エドワード＝ブラウン フィルタ RGB(119,255,119) 50%
すまないが時間だ。私も多忙でな
少佐、我らの目的は同じだ。人類の敵インベーダーを打ち滅ぼすため、力を尽くしてくれたまえ
Talk ソフィア＝コールドウェル
了解しました
Suspend
Wait 5
PlaySound WindowClose.wav
Talk ソフィア＝コールドウェル
(禿狸め、一体何を隠しているんだ…？)
(『Ｆ．Ｇ計画』にネスト攻略作戦、それにインベーダーの正体……)
(この戦争、思ったより単純なものではないかも知れんな)
End

Continue Eve\Episode-04.eve

####  エピローグ  ####################################################

エピローグ:

RemoveItem ジャック 予備弾薬
RemoveItem エメリア 予備弾薬
RemoveItem ウィル 予備弾薬
UpGrade サテライト社製ＶＭＡクラウドフェザー(ビーム砲装備型) サテライト社製ＶＭＡクラウドフェザー(狙撃型)
RemoveItem ユキノ 包帯ユキノ

Set LibraryFlag[アーカシア] 1
Set LibraryFlag[ガン・ゴーレム] 1
Set LibraryFlag[ソード・ゴーレム] 1
Set LibraryFlag[タンク・ゴーレム] 1
Set LibraryFlag[ツインヘッド] 1

Set LibraryFlag[ユキノ] 2
Set LibraryFlag[ニコライ] 1
Set LibraryFlag[ブラウン司令] 1

Exit

