#　ヒットアンドアウェイ再現VerB  最終更新：2005/ 5/22
#　制作：蒼城 醒
#
@Ｈ＆Ａ

*ターン 全 全:
Local tmp
Unset BBvar_HA
Unset BBvar_HAOn
Unset BBvar_CX
Unset BBvar_CY
ForEach フェイズ 出撃
	Set tmp UnitID()
	If Not Info(パイロット,PilotID(tmp),特殊能力所有,一撃離脱) Then
		Skip
	ElseIf IsEquiped(tmp,攻撃不能アイテム) Then
		RemoveItem tmp 攻撃不能アイテム
	EndIf
	Set BBvar_CX[tmp] X(tmp)
	Set BBvar_CY[tmp] Y(tmp)
Next
Exit

*攻撃 全 全:
Local tmp
Set tmp 対象ユニットＩＤ
If Not Info(パイロット,PilotID(tmp),特殊能力所有,一撃離脱) Exit
If BBSR_CompareCoordinate(tmp) Then
	Set BBvar_HA[tmp]
EndIf
Exit

*行動終了 全:
Local tmp
Set tmp 対象ユニットＩＤ
If Not Info(パイロット,PilotID(tmp),特殊能力所有,一撃離脱) Exit
If BBvar_HA[tmp] Then
	SpecialPower tmp 覚醒
	If Party(tmp) = 味方 Then
		Item 攻撃不能アイテム
	EndIf
	Equip tmp 攻撃不能アイテム
	Set BBvar_HAOn[tmp]
	Unset BBvar_HA[tmp]
ElseIf  BBvar_HAOn[tmp] Then
	RemoveItem tmp 攻撃不能アイテム
	Unset BBvar_HAOn[tmp]
EndIf
Set BBvar_CX[tmp] X(tmp)
Set BBvar_CY[tmp] Y(tmp)
Exit

# その場に留まるコマンドっぽいもの
ユニットコマンド 待機 全 (BBvar_HAOn[対象ユニットＩＤ]):
Local tmp
Set tmp 対象ユニットＩＤ
RemoveItem tmp 攻撃不能アイテム
Unset BBvar_HAOn[tmp]
Finish
Exit

BBSR_CompareCoordinate:
If (X(Args(1)) = BBvar_CX[Args(1)]) And (Y(Args(1)) = BBvar_CY[Args(1)]) Then
	Return 1
EndIf
Return 0

