####################################################
#第2次ＳＲＷα風ステータス表示ver13.02＆辞典ver6.05#
####################################################

リンクしてるの:
Return 5963

キャラクター紹介表示:
If EncyclopediaDataType = 1 Then
	Require Data\辞典データ\キャラクターデータ.DAT
Else
	If でーたよんだ = 0 Then
		<Data\辞典データ\キャラクターデータ.DAT>
		でーたよんだ = 1
	EndIf
EndIf
Set 段目 1
キャラ紹介作成 Args(1) Args(2) Args(3)
Local あーぐす2
Local あーぐす3
あーぐす2 = Args(2)
あーぐす3 = Args(3)
Do
	Wait click
	Switch 選択
	Case 次の人
		UnSet 切り替え画像
		UnSet きりかえすう
		UnSet きりかえばん
		Set 段目 1
		If あーぐす3 = 45 Then
			Incr あーぐす2
			あーぐす3 = 1
		Else
			Incr あーぐす3
		EndIf
		If 名簿[あーぐす2,あーぐす3] = "" Then
			あーぐす2 = 1
			あーぐす3 = 1
		EndIf
		キャラ紹介作成 名簿[あーぐす2,あーぐす3] あーぐす2 あーぐす3
	Case 前の人
		UnSet 切り替え画像
		UnSet きりかえすう
		UnSet きりかえばん
		Set 段目 1
		If あーぐす3 = 1 Then
			Incr あーぐす2 -1
			あーぐす3 = 45
			If あーぐす2 < 1 Then
				あーぐす2 = ページ数
				あーぐす3 = (キャラ数 - 45 * (ページ数 - 1))
			EndIf
		Else
			Incr あーぐす3 -1
		EndIf
		キャラ紹介作成 名簿[あーぐす2,あーぐす3] あーぐす2 あーぐす3
	Case 戻る ""
		If (選択 = "") And (KeyState(2) <> 1) Then
			Skip
		Else
			Do While KeyState(2)
			Loop
			Wait 1
			If Args(3) <> "" Then
				今のページ = あーぐす2
				UnSet きゃらくたー
				UnSet あいしょー
				UnSet なめー
				UnSet 段目
				UnSet 切り替え画像
				UnSet きりかえすう
				UnSet きりかえばん
				Break
			Else
				UnSet TITLEDAT
				UnSet UNITGRAPHIC
				UnSet FULLNAME
				UnSet CARDAT
				UnSet VOICEDAT
				UnSet GRAPHIC
				UnSet COMMENT
				UnSet COMMENTCAR
				UnSet きゃらくたー
				UnSet あいしょー
				UnSet なめー
				UnSet 段目
				UnSet 切り替え画像
				UnSet きりかえすう
				UnSet きりかえばん
				UnSet でーたよんだ
				ClearObj
				ClearPicture
				Break
			EndIf
		EndIf
	Case 一言
		PaintPicture \event\一言ボタン.png 22 135 ネガポジ反転
		Refresh
		Local しゃべるひと
		If COMMENTCAR[きゃらくたー] <> "" Then
			しゃべるひと = COMMENTCAR[きゃらくたー]
		Else
			しゃべるひと = きゃらくたー
		EndIf
		Talk しゃべるひと
		$(COMMENT[きゃらくたー])
		End
		PaintPicture \event\一言ボタン.png 22 135
		Refresh
	Case 画像切り替え
		Incr きりかえばん
		If きりかえばん > きりかえすう Then
			きりかえばん = 1
		EndIf
		PaintPicture 切り替え画像[きりかえばん] 272 32 192 192
		名称等データ表示
		Refresh
	Case 下へ
		段目 = (段目 + 1)
		If Args(3) <> "" Then
			キャラ紹介作成 名簿[あーぐす2,あーぐす3] あーぐす2 あーぐす3 切り替え画像[きりかえばん]
		Else
			キャラ紹介作成 きゃらくたー あーぐす2 あーぐす3 切り替え画像[きりかえばん]
		EndIf
	Case 上へ
		段目 = (段目 - 1)
		If Args(3) <> "" Then
			キャラ紹介作成 名簿[あーぐす2,あーぐす3] あーぐす2 あーぐす3 切り替え画像[きりかえばん]
		Else
			キャラ紹介作成 きゃらくたー あーぐす2 あーぐす3 切り替え画像[きりかえばん]
		EndIf
		Refresh
	EndSw
Loop While (1)
Return

キャラ紹介作成:
Local キリカエアリ
キリカエアリ = 0
ClearObj
ClearPicture
If BGGraphic = "On" Then
	PaintPicture BackGround - - 480 480 BackGroundOption
Else
	Line 0 0 479 479 BF BackGroundColor
EndIf
Line 272 32 463 223 B #4a4a4a
If ReservePict = "On" Then
	PaintPicture ReservePilotPicture 272 32 192 192
EndIf
If Args(3) <> "" Then
	きゃらくたー = Args(1)
	If EncyclopediaDataType = 1 Then
		If TITLEDAT[きゃらくたー] = "" Then
			キャラ紹介文セット きゃらくたー
		EndIf
	EndIf
	If フルネーム[きゃらくたー] <> "" Then
		なめー = フルネーム[きゃらくたー]
	ElseIf InStr(きゃらくたー,"(") = 0 Then
		なめー = きゃらくたー
	Else
		なめー = Left(きゃらくたー,(InStr(きゃらくたー,"(") - 1))
	EndIf
	あいしょー = Info(パイロットデータ,きゃらくたー,愛称)
	If あいしょー = "" Then
		あいしょー = Info(非戦闘員,きゃらくたー,愛称)
	EndIf
	If Args(4) <> "" Then
		PaintPicture Args(4) 272 32 192 192
		キリカエアリ = 1
	Else
		If GRAPHIC[きゃらくたー] <> "" Then
			If InStr(GRAPHIC[きゃらくたー],":") Then
				UnSet 切り替え画像
				UnSet きりかえすう
				キリカエアリ = 1
				Local こんてん
				こんてん = GRAPHIC[きゃらくたー]
				きりかえばん = 1
				きりかえすう = 1
				Do
					If InStr(こんてん,":") Then
						Incr きりかえすう
						切り替え画像[きりかえすう - 1] = Left(こんてん,(InStr(こんてん,":") - 1))
						こんてん = Right(こんてん,(Len(こんてん) - InStr(こんてん,":")))
					Else
						Break
					EndIf
				Loop While (1)
				切り替え画像[きりかえすう] = こんてん
				PaintPicture 切り替え画像[きりかえばん] 272 32 192 192
			Else
				PaintPicture GRAPHIC[きゃらくたー] 272 32 192 192
			EndIf
		ElseIf Info(パイロットデータ,きゃらくたー,グラフィック) <> "" Then
			PaintPicture ("Pilot\" & Info(パイロットデータ,きゃらくたー,グラフィック)) 272 32 192 192
		Else
			PaintPicture ("Pilot\" & Info(非戦闘員,きゃらくたー,グラフィック)) 272 32 192 192
		EndIf
	EndIf
Else
	きゃらくたー = 搭乗員[Args(2),5]
	If EncyclopediaDataType = 1 Then
		If TITLEDAT[きゃらくたー] = "" Then
			キャラ紹介文セット きゃらくたー
		EndIf
	EndIf
	If Args(4) <> "" Then
		PaintPicture Args(4) 272 32 192 192
		キリカエアリ = 1
	Else
		If GRAPHIC[きゃらくたー] <> "" Then
			If InStr(GRAPHIC[きゃらくたー],":") Then
				UnSet 切り替え画像
				UnSet きりかえすう
				キリカエアリ = 1
				Local こんてん
				こんてん = GRAPHIC[きゃらくたー]
				きりかえばん = 1
				きりかえすう = 1
				Do
					If InStr(こんてん,":") Then
						Incr きりかえすう
						切り替え画像[きりかえすう - 1] = Left(こんてん,(InStr(こんてん,":") - 1))
						こんてん = Right(こんてん,(Len(こんてん) - InStr(こんてん,":")))
					Else
						Break
					EndIf
				Loop While (1)
				切り替え画像[きりかえすう] = こんてん
				PaintPicture 切り替え画像[きりかえばん] 272 32 192 192
			Else
				PaintPicture GRAPHIC[きゃらくたー] 272 32 192 192
			EndIf
		Else
			PaintPicture 搭乗員[Args(2),4] 272 32 192 192
		EndIf
	EndIf
	あいしょー = 搭乗員[Args(2),3]
	なめー = 搭乗員[Args(2),2]
EndIf
If UNITGRAPHIC[きゃらくたー] <> "" Then
	Local unigra
	unigra = ScenarioPath & "\Bitmap\Unit\" & UNITGRAPHIC[きゃらくたー]
	PaintPicture unigra 125 96 128 128 透過
EndIf
PaintPicture \event\辞典用三角2.png 222 9 透過 上下反転
PaintPicture \event\辞典用三角3.png 1 222 透過
PaintPicture \event\辞典用三角3.png 467 222 透過 左右反転
Line 16 64 255 64 B FrameColor1
Line 16 240 463 463 B FrameColor1
Font 16pt Ｐゴシック
yellowPaintString 20 70 "愛称"
yellowPaintString 20 95 "声優"
yellowPaintString 20 170 登場作品
名称等データ表示
If COMMENT[きゃらくたー] <> "" Then
	PaintPicture \event\一言ボタン.png 22 135
EndIf
If Args(3) <> "" Then
	PaintPicture \event\辞典用三角.png 1 222 透過
	PaintPicture \event\辞典用三角.png 467 222 左右反転 透過
EndIf
If CARDAT[きゃらくたー,1] <> "" Then
	If KEYDAT[きゃらくたー] <> "" Then
		If IsNumeric(KEYDAT[きゃらくたー]) = 1 Then
			If KEYDAT[きゃらくたー] < (辞典達成度 + 1) Then
				文書表示 きゃらくたー 段目
			Else
				Font 40pt Regular
				whitePaintString ((480 - TextWidth(SECRET)) / 2) ((702 - TextHeight(SECRET)) / 2) "SECRET"
			EndIf
		ElseIf 特殊追加[KEYDAT[きゃらくたー]] = 1 Then
			文書表示 きゃらくたー 段目
		Else
			Font 40pt Regular
			whitePaintString ((480 - TextWidth(SECRET)) / 2) ((702 - TextHeight(SECRET)) / 2) "SECRET"
		EndIf
	Else
		文書表示 きゃらくたー 段目
	EndIf
Else
	Font 40pt Regular
	whitePaintString ((480 - TextWidth(NO DATA)) / 2) ((702 - TextHeight(NO DATA)) / 2) "NO DATA"
EndIf
HotPoint 戻る 200 0 80 32 戻る
If COMMENT[きゃらくたー] <> "" Then
	HotPoint 一言 22 135 16 16 一言
EndIf
If Args(3) <> "" Then
	HotPoint 次の人 464 57 16 407 次へ
	HotPoint 前の人 0 57 16 407 前へ
EndIf
If キリカエアリ = 1 Then
	HotPoint 画像切り替え 272 32 192 192
EndIf
Refresh
Font
Return

名称等データ表示:
Font 13pt Ｐゴシック
If FULLNAME[きゃらくたー] <> "" Then
	whitePaintString 20 40 FULLNAME[きゃらくたー]
Else
	whitePaintString 20 40 なめー
EndIf
whitePaintString 70 72 あいしょー
If VOICEDAT[きゃらくたー] <> "" Then
	whitePaintString 70 97 VOICEDAT[きゃらくたー]
Else
	whitePaintString 70 97 "--"
EndIf
If TITLEDAT[きゃらくたー] <> "" Then
	If InStr(TITLEDAT[きゃらくたー],":") Then
		bluePaintString 20 200 Left(TITLEDAT[きゃらくたー],(InStr(TITLEDAT[きゃらくたー],":") - 1))
		bluePaintString 20 217 Right(TITLEDAT[きゃらくたー],(Len(TITLEDAT[きゃらくたー]) - InStr(TITLEDAT[きゃらくたー],":")))
	Else
		bluePaintString 20 200 TITLEDAT[きゃらくたー]
	EndIf
Else
	bluePaintString 20 200 "NO DATA"
EndIf
Font
Return

次と前のページあるの:
Font 12pt Ｐゴシック Regular
If CARDAT[Args(1),(Args(2) + 10)] <> "" Then
	bluePaintString 445 445 ▽
EndIf
If Args(2) <> 1 Then
	bluePaintString 445 245 △
EndIf
If CARDAT[Args(1),(Args(2) + 10)] <> "" Then
	HotPoint 下へ 445 445 TextWidth(▽) TextHeight(▽) 下
EndIf
If Args(2) <> 1 Then
	HotPoint 上へ 445 245 TextWidth(△) TextHeight(△) 上
EndIf
Font
Return

文書表示:
Font 12pt Ｐゴシック Regular
Local i
For i = 1 To 10
	whitePaintString 23 (227 + 21 * i) CARDAT[Args(1),(Args(2) + i - 1)]
Next
次と前のページあるの Args(1) Args(2)
Font
Return

ユニット紹介表示:
If EncyclopediaDataType = 1 Then
	Require Data\辞典データ\ユニットデータ.DAT
Else
	If ゆにっとでーたよんだ = 0 Then
		<Data\辞典データ\ユニットデータ.DAT>
		ゆにっとでーたよんだ = 1
	EndIf
EndIf
Local あーぐす1
Local あーぐす2
Local あーぐす3
Local 段目
あーぐす1 = Args(1)
あーぐす2 = Args(2)
あーぐす3 = Args(3)
段目 = 1
Do
	ユニット紹介作成 あーぐす1 あーぐす2 あーぐす3 段目
	Refresh
	Wait click
	Switch 選択
	Case 次の人
		If あーぐす3 = 30 Then
			Incr あーぐす2
			あーぐす3 = 1
		Else
			Incr あーぐす3
		EndIf
		If 名簿[あーぐす2,あーぐす3] = "" Then
			あーぐす2 = 1
			あーぐす3 = 1
		EndIf
		あーぐす1 = 名簿[あーぐす2,あーぐす3]
		段目 = 1
	Case 前の人
		If あーぐす3 = 1 Then
			Incr あーぐす2 -1
			あーぐす3 = 30
			If あーぐす2 < 1 Then
				あーぐす2 = ページ数
				あーぐす3 = (ユニット数 - 30 * (ページ数 - 1))
			EndIf
		Else
			Incr あーぐす3 -1
		EndIf
		あーぐす1 = 名簿[あーぐす2,あーぐす3]
		段目 = 1
	Case 戻る ""
		If (選択 = "") And (KeyState(2) <> 1) Then
			Skip
		Else
			Do While KeyState(2)
			Loop
			Wait 1
			If Args(3) <> "" Then
				今のページ = あーぐす2
				Break
			Else
				UnSet TITLEDAT
				UnSet FULLNAME
				UnSet CARDAT
				UnSet HEIGHTDAT
				UnSet WEIGHTDAT
				UnSet ゆにっとでーたよんだ
				ClearObj
				ClearPicture
				Break
			EndIf
		EndIf
	Case 下へ
		段目 = (段目 + 1)
	Case 上へ
		段目 = (段目 - 1)
	EndSw
Loop While (1)
Return

ユニット紹介作成:
ClearObj
ClearPicture
If EncyclopediaDataType = 1 Then
	If TITLEDAT[Args(1)] = "" Then
		ユニット紹介文セット Args(1)
	EndIf
EndIf
If BGGraphic = "On" Then
	PaintPicture BackGround - - 480 480 BackGroundOption
Else
	Line 0 0 479 479 BF BackGroundColor
EndIf
If Info(ユニットデータ,Args(1),特殊能力所有,全身画像) = 1 Then
	If LIndex(Info(ユニットデータ,Args(1),特殊能力データ,全身画像),3) = "" Then
		PaintPicture LIndex(Info(ユニットデータ,Args(1),特殊能力データ,全身画像),2) (144 + ShiftEncUnitGraphicX) (32 + ShiftEncUnitGraphicY) 192 192 透過
	Else
		Local YokoSize
		Local TateSize
		YokoSize = LIndex(Info(ユニットデータ,Args(1),特殊能力データ,全身画像),3)
		TateSize = LIndex(Info(ユニットデータ,Args(1),特殊能力データ,全身画像),4)
		Local YokoIti
		Local TateIti
		If LIndex(Info(ユニットデータ,Args(1),特殊能力データ,全身画像),5) = "" Then
			YokoIti = 0
			TateIti = 0
		Else
			YokoIti = LIndex(Info(ユニットデータ,Args(1),特殊能力データ,全身画像),5)
			TateIti = LIndex(Info(ユニットデータ,Args(1),特殊能力データ,全身画像),6)
		EndIf
		PaintPicture LIndex(Info(ユニットデータ,Args(1),特殊能力データ,全身画像),2) (144 + ShiftEncUnitGraphicX + YokoIti + (192 - YokoSize ) / 2) (32 + ShiftEncUnitGraphicY + TateIti + (192 - TateSize ) / 2) YokoSize TateSize 透過
	EndIf
Else
	PaintPicture ("Unit\" & Info(ユニットデータ,Args(1),グラフィック)) (144 + ShiftEncUnitGraphicX) (32 + ShiftEncUnitGraphicY) 192 192 透過
EndIf
PaintPicture \event\辞典用三角2.png 222 9 透過 上下反転
PaintPicture \event\辞典用三角3.png 1 222 透過
PaintPicture \event\辞典用三角3.png 467 222 透過 左右反転
Line 16 64 143 64 B FrameColor1
Line 16 240 463 463 B FrameColor1
Font 16pt Ｐゴシック
yellowPaintString 20 170 登場作品
If Left(Info(ユニットデータ,Args(1),ユニットクラス),1) = "(" Then
	yellowPaintString 20 70 "身長"
	yellowPaintString 20 95 "体重"
Else
	yellowPaintString 20 70 "全長"
	yellowPaintString 20 95 "重量"
EndIf
Font 13pt
If FULLNAME[Args(1)] <> "" Then
	whitePaintString 20 40 FULLNAME[Args(1)]
Else
	whitePaintString 20 40 Info(ユニットデータ,Args(1),愛称)
EndIf
If TITLEDAT[Args(1)] <> "" Then
	If InStr(TITLEDAT[Args(1)],":") Then
		bluePaintString 20 200 Left(TITLEDAT[Args(1)],(InStr(TITLEDAT[Args(1)],":") - 1))
		bluePaintString 20 217 Right(TITLEDAT[Args(1)],(Len(TITLEDAT[Args(1)]) - InStr(TITLEDAT[Args(1)],":")))
	Else
		bluePaintString 20 200 TITLEDAT[Args(1)]
	EndIf
Else
	bluePaintString 20 200 "NO DATA"
EndIf
If HEIGHTDAT[Args(1)] <> "" Then
	whitePaintString 70 72 HEIGHTDAT[Args(1)]
Else
	whitePaintString 70 72 "--"
EndIf
If WEIGHTDAT[Args(1)] <> "" Then
	whitePaintString 70 97 WEIGHTDAT[Args(1)]
Else
	whitePaintString 70 97 "--"
EndIf
段目 = 1
If CARDAT[Args(1),1] <> "" Then
	If KEYDAT[Args(1)] <> "" Then
		If IsNumeric(KEYDAT[Args(1)]) = 1 Then
			If KEYDAT[Args(1)] < (辞典達成度 + 1) Then
				U文書表示 Args(1) Args(4)
			Else
				Font 40pt Ｐ明朝 Regular
				whitePaintString ((480 - TextWidth(SECRET)) / 2) ((702 - TextHeight(SECRET)) / 2) "SECRET"
			EndIf
		ElseIf 特殊追加[KEYDAT[Args(1)]] = 1 Then
			文書表示 Args(1) Args(4)
		Else
			Font 40pt Ｐ明朝 Regular
			whitePaintString ((480 - TextWidth(SECRET)) / 2) ((702 - TextHeight(SECRET)) / 2) "SECRET"
		EndIf
	Else
		U文書表示 Args(1) Args(4)
	EndIf
Else
	Font 40pt Ｐ明朝 Regular
	whitePaintString ((480 - TextWidth(NO DATA)) / 2) ((702 - TextHeight(NO DATA)) / 2) "NO DATA"
EndIf
HotPoint 戻る 200 0 80 32 戻る
If Args(3) <> "" Then
	HotPoint 次の人 464 57 16 407 次へ
	HotPoint 前の人 0 57 16 407 前へ
	PaintPicture \event\辞典用三角.png 1 222 透過
	PaintPicture \event\辞典用三角.png 467 222 左右反転 透過
EndIf
Refresh
Font
Return

U次のページあるの:
If CARDAT[Args(1),(Args(2) + 10)] <> "" Then
	Font 12pt Ｐゴシック Regular
	bluePaintString 445 445 ▽
	HotPoint 下へ 445 445 TextWidth(▽) TextHeight(▽) 下
	Font
EndIf
Return

U前のページあるの:
If Args(2) <> 1 Then
	Font 12pt Ｐゴシック Regular
	bluePaintString 445 245 △
	HotPoint 上へ 445 245 TextWidth(△) TextHeight(△) 上
	Font
EndIf
Return

U文書表示:
Font 12pt Ｐゴシック Regular
Local i
For i = 1 To 10
	whitePaintString 23 (227 + 21 * i) CARDAT[Args(1),(Args(2) + i - 1)]
Next
U次のページあるの Args(1) Args(2)
U前のページあるの Args(1) Args(2)
Font
Return

yellowPaintString:
Font LetterShadow
PaintString (Args(1) + 1) (Args(2) + 1) Args(3)
Font LetterColor2
PaintString Args(1) Args(2) Args(3)
Return

bluePaintString:
Font LetterShadow
PaintString (Args(1) + 1) (Args(2) + 1) Args(3)
Font LetterColor3
PaintString Args(1) Args(2) Args(3)
Return

whitePaintString:
Font LetterShadow
PaintString (Args(1) + 1) (Args(2) + 1) Args(3)
Font LetterColor1
PaintString Args(1) Args(2) Args(3)
Return

grayPaintString:
Font LetterShadow
PaintString (Args(1) + 1) (Args(2) + 1) Args(3)
Font LetterColor4
PaintString Args(1) Args(2) Args(3)
Return
